Update service in quotation document (RFQ)

A quotation document can have service lines instead of normal material lines. It is an external component of the document, here we will see how to update service line.

The functionality for managing services is in the function group MLSP. How service is integrated is described here.

These are following steps to update service line:

1. Read service data in internal table of the function group. This is achieved by function module MS_GET_SERVICES.
2. Set data in the internal table by calling function module MS_FILL_TABS_FROM_EXT_DATA and MS_CHANGE_SERVICE_PACKAGE.
3. After that save by calling MS_SAVE_SERVICE_PACKAGE.

The function call requires communication structure COMSRV. This can be filled from the structure EKKO and EKPO. It is important that COMSRV-REF_BSTYP is set to ‘C’ (change). Refer function module BAPI_PO_CHANGE.

WebDynpro: Progress indicator (similar to SAPGUI_PROGRESS_INDICATOR)

Within normal ABAP reporting, if we are doing some long queries or posting a lot of transactions we would use the FM SAPGUI_PROGRESS_INDICATOR to stop the report from timing out. The same scenario can happen in WebDynpro as well. By default a WebDynpro application times out in 5 minutes. So posting a lot of transaction becomes a problem here too. WebDynpro does not provide a similar function to SAPGUI_PROGRESS_INDICATOR yet (coming in 7.1?).

So we would have to implement our own progress indicator by creating a WebDynpro component using UI elements TimedTrigger and ProgressIndicator. UI element TimedTrigger is an invisible element which when placed on a view, triggers an event every given number of seconds. This is an expensive UI element to have as it creates additional burden on the server, but we have no choice so we will use this. UI element ProgressIndicator is used to show a progress bar. So the idea is to split big job into chunks that can be done in small amount of time (less than the time out period). Every time TimedTrigger fires an event we process the next available chunk of work and set the progress bar and so on.

The calling WD component will use this component for displaying the progress bar and getting a timed wake up call. The calling WD will already have the dataset ready. It would decide how many chunks the dataset will be needed divide into. So once the user triggers the action this progress indicator (PI) WD component is called in a dialog window. The calling WD subscribes to the PI WD event of timed trigger so that it wakes up to send next chunk of data. Using the assistance class of PI WD the calling WD will set the percentage of data completion as well so that the progress bar will keep on increasing.

Let’s see what we need to create in this PI WD component:

UI elements in the view

Layout

Components

Context

Events

Methods of the Component Controller

ACTION_KEEP_ALIVE	call from timed trigger
GET_MODEL	Return the model class
INIT_PROG_VIEW	Initialise progress view
RAISE_WINDOW_CLOSE	Raise event for window closed
SET_PERCENTAGE	Set percentage complete
SET_PROGRESS_MSG	Set progress message

ACTION_KEEP_ALIVE
METHOD action_keep_alive . 
  set_percentage( ).
  wd_this->fire_keep_alive_evt( ). 
ENDMETHOD.

GET_MODEL
METHOD get_model .
  r_o_model = wd_assist.
ENDMETHOD.

INIT_PROG_VIEW
method INIT_PROG_VIEW .
  wd_assist->set_percent_comp( 0 ).
  wd_this->set_percentage( ).
  wd_this->set_progress_msg( ).
endmethod.

RAISE_WINDOW_CLOSE
METHOD raise_window_close .
  wd_this->fire_window_close_evt(
  ). 
ENDMETHOD.

SET_PERCENTAGE
METHOD set_percentage .
  DATA lo_nd_progress TYPE REF TO if_wd_context_node.
  DATA lo_el_progress TYPE REF TO if_wd_context_element.
  DATA ls_progress TYPE wd_this->element_progress.
  DATA lv_percent LIKE ls_progress-percent.
* navigate from <CONTEXT> to <PROGRESS> via lead selection
  lo_nd_progress = wd_context->get_child_node( name = wd_this->wdctx_progress ).
 
* get element via lead selection
  lo_el_progress = lo_nd_progress->get_element(  ).
 
  lv_percent = wd_assist->get_percent_comp( ).
* get single attribute
  lo_el_progress->set_attribute(
    EXPORTING
      name =  `PERCENT`
      value = lv_percent ). 
ENDMETHOD.

SET_PROGRESS_MSG
METHOD set_progress_msg .
  DATA lo_nd_progress TYPE REF TO if_wd_context_node.
  DATA lo_el_progress TYPE REF TO if_wd_context_element.
  DATA ls_progress TYPE wd_this->element_progress.
  DATA lv_message LIKE ls_progress-message.
*   navigate from <CONTEXT> to <PROGRESS> via lead selection
  lo_nd_progress = wd_context->get_child_node( name = wd_this->wdctx_progress ).
 
*   get element via lead selection
  lo_el_progress = lo_nd_progress->get_element(  ).
 
  lv_message = wd_assist->get_progress_msg( ).
*   get single attribute
  lo_el_progress->set_attribute(
    EXPORTING
      name =  `MESSAGE`
      value = lv_message ).
ENDMETHOD.

The assistance class has these methods:

GET_PROGRESS_MSG	Get the progress message
SET_PROGRESS_MSG	Set the message in the progress bar
SET_PERCENT_COMP	Returns the percentage done
GET_PERCENT_COMP	Returns the percentage done

These are just getter and setter methods for the filling the Context variables. The calling WD component can set the percentage and message to be displayed. The PI WD will read these values and set in the context.

Usage

Let’s look at the usage of the progress indicator in a example WD component. Create a new WD where we will use the PI WD component. Add the PI WD component in the properties.

In the component controller properties add it as used component comptroller.

Subscribe to the events of the PI WD component.

This catches events for timed trigger and window close in case user cancels before 100% completion of the process.

CATCH_TIMED_TRIGGER
METHOD catch_timed_trigger .
  DATA l_percentage TYPE i.
  l_percentage = wd_this->o_zcl_rc_library->get_percent_comp( ).
  IF l_percentage >= 100.
    wd_this->o_progress_window->close( ).
  ENDIF.
 
  l_percentage = l_percentage + 10.
 
  wd_this->o_zcl_rc_library->set_percent_comp( l_percentage ).
 
ENDMETHOD.

We are here just incrementing the percentage by 10% each time the trigger is activated. But in real situation one would increment to the next dataset that is planned to be processed. The percentage will be according to that.

CATCH_WINDOW_CLOSE
METHOD catch_window_close .
 
* Check action is over because it is finished or
* killed in between
  CHECK wd_this->flag_action_start = abap_true. " Action is killed
  " ERROR
 
*   get message manager
  DATA lo_api_controller     TYPE REF TO if_wd_controller.
  DATA lo_message_manager    TYPE REF TO if_wd_message_manager.
 
  lo_api_controller ?= wd_this->wd_get_api( ).
 
  lo_message_manager = lo_api_controller->get_message_manager( ).
 
*   report message
  lo_message_manager->report_error_message(
      message_text             = 'Window cancelled before process completion'
         ).
 
* Clear variables
  CASE wd_this->action.
    WHEN 1. " Validate
 
    WHEN 2. " Action
 
    WHEN OTHERS.
  ENDCASE.
 
 
ENDMETHOD.

If the progress window is closed before all data has been processed you can alert the user that with that error.

Let’s look at the component controllers methods.

WDDOINIT
METHOD wddoinit .
  DATA lo_cmp_usage TYPE REF TO if_wd_component_usage.
 
  lo_cmp_usage =   wd_this->wd_cpuse_zwdrc_progress_window( ).
  IF lo_cmp_usage->has_active_component( ) IS INITIAL.
    lo_cmp_usage->create_component( ).
  ENDIF.
 
  DATA lo_interfacecontroller TYPE REF TO ziwci_wdrc_progress_window .
  lo_interfacecontroller =   wd_this->wd_cpifc_zwdrc_progress_window( ).
 
  wd_this->o_zcl_rc_library = lo_interfacecontroller->get_model( ).
 
 
ENDMETHOD.

This will initialise the PI WD component and get the assistance class handler.

We have a simple example which has a button that will launch the progress window.

The action attached to the button is:

ONACTIONCALL_PROGRESS
METHOD onactioncall_progress .
  wd_comp_controller->open_progress_window( ).
ENDMETHOD.

Here the real application would start the working of whatever transaction was planned. The progress window is further opened as:

OPEN_PROGRESS_WINDOW
METHOD open_progress_window .
  DATA lo_componentinterface TYPE REF TO if_wd_component_usage.
  lo_componentinterface = wd_this->wd_cpuse_zwdrc_progress_window( ).
  DATA lo_interface TYPE REF TO ziwci_wdrc_progress_window.
  lo_interface = wd_this->wd_cpifc_zwdrc_progress_window( ).
 
  wd_this->o_zcl_rc_library->set_progress_msg( 'We are doing it ').
  wd_this->o_zcl_rc_library->set_percent_comp( 0 ).
  DATA lo_cont TYPE REF TO if_wd_controller.
 
*  if_wd_controller = lo_interface->wd_get_api( ).
  DATA lo_api_componentcontroller TYPE REF TO if_wd_component.
  lo_api_componentcontroller = wd_this->wd_get_api( ).
 
  DATA l_window_manager    TYPE REF TO if_wd_window_manager.
  l_window_manager    = lo_api_componentcontroller->get_window_manager( ).
 
  wd_this->o_progress_window = l_window_manager->create_window_for_cmp_usage(
      interface_view_name  = 'W_MAIN'
      component_usage_name = 'ZWDRC_PROGRESS_WINDOW'
      title                = 'We are doing it'
*    close_in_any_case    = ABAP_TRUE
*    message_display_mode = message_display_mode
         ).
*  wd_this->o_progress_window->set_window_title( title = 'Test' ).
  wd_this->o_progress_window->open( ).
ENDMETHOD.

Here the window W_MAIN of PI WD component is being called. The title is set and so is the message that will come in the message bar.

Here is the example of the output:

10% done

20% done

WebDynpro: Upload and Download file, part III (usage)

Let’s see how to make use of the download and upload components in this section. We will upload a file to show it on the browser and then change contents of the file and download it.

Upload Screen which leads to…Download Screen

Download Screen which goes back to…Upload screen

Used WebDynpro components

Controller usage

Component list

Window layout

Context for Component controller

In the init of the component controller we will initiate the used components and get reference to the respective assistance class. For the download component we fill the file node with the file name and mime type.

METHOD wddoinit .
  DATA lo_cmp_usage TYPE REF TO if_wd_component_usage.
 
* Download component
  lo_cmp_usage =   wd_this->wd_cpuse_download_file( ).
  IF lo_cmp_usage->has_active_component( ) IS INITIAL.
    lo_cmp_usage->create_component( ).
  ENDIF.
  DATA lo_ziwci_wdrc_download_file TYPE REF TO ziwci_wdrc_download_file .
  lo_ziwci_wdrc_download_file =   wd_this->wd_cpifc_download_file( ).
 
  wd_this->o_model_download = lo_ziwci_wdrc_download_file->get_model(
  ).
 
* Give file name and specify mime type
  DATA lo_nd_file TYPE REF TO if_wd_context_node.
  DATA lo_el_file TYPE REF TO if_wd_context_element.
  DATA ls_file TYPE wd_this->element_file.
*   navigate from <CONTEXT> to <FILE> via lead selection
  lo_nd_file = wd_context->get_child_node( name = wd_this->wdctx_file ).
 
*   get element via lead selection
  lo_el_file = lo_nd_file->get_element(  ).
 
  ls_file-filename = 'up_down_text.txt'.
  ls_file-mimetype = 'Text'.
*   set all declared attributes
  lo_el_file->set_static_attributes(
    EXPORTING
      static_attributes = ls_file ).
 
* Upload component
  lo_cmp_usage =   wd_this->wd_cpuse_upload_file( ).
  IF lo_cmp_usage->has_active_component( ) IS INITIAL.
    lo_cmp_usage->create_component( ).
  ENDIF.
  DATA lo_ziwci_wdrc_upload_file TYPE REF TO ziwci_wdrc_upload_file .
  lo_ziwci_wdrc_upload_file =   wd_this->wd_cpifc_upload_file( ).
 
  wd_this->o_model_upload = lo_ziwci_wdrc_upload_file->get_model(
  ).
 
ENDMETHOD.

Events handler

Upload event handler reads the data by calling the assistance class method get_mapped_file and binds the node table_data to the returned table.

METHOD catch_upload .
  DATA lo_nd_table_data TYPE REF TO if_wd_context_node.
  DATA lo_el_table_data TYPE REF TO if_wd_context_element.
  DATA ls_table_data TYPE wd_this->element_table_data.
  DATA lt_data TYPE TABLE OF wd_this->element_table_data.
 
  wd_this->o_model_upload->get_mapped_file( IMPORTING e_t_mapped_file = lt_data ).
 
* navigate from <CONTEXT> to <TABLE_DATA> via lead selection
  lo_nd_table_data = wd_context->get_child_node( name = wd_this->wdctx_table_data ).
 
  lo_nd_table_data->bind_table( EXPORTING new_items = lt_data ).
 
ENDMETHOD.

Download event handler does a bit more than upload event catcher. It has to convert the data in the node table_data into file structure. It does that by calling the method covert_struc2file in the assistance class. Once the conversion is done then call the interface method download_file of download WD component that will push the file out of the browser.

METHOD catch_download .
  DATA lo_nd_table_data TYPE REF TO if_wd_context_node.
  DATA lo_el_table_data TYPE REF TO if_wd_context_element.
  DATA ls_table_data TYPE wd_this->element_table_data.
  DATA lt_data TYPE TABLE OF wd_this->element_table_data.
*   navigate from <CONTEXT> to <TABLE_DATA> via lead selection
  lo_nd_table_data = wd_context->get_child_node( name = wd_this->wdctx_table_data ).
 
*   @TODO handle not set lead selection
  IF lo_nd_table_data IS INITIAL.
    RETURN.
  ENDIF.
 
* Get table data
  lo_nd_table_data->get_static_attributes_table( IMPORTING table = lt_data ).
 
* Send data to be converted
  TRY .
      wd_this->o_model_download->convert_struc2file( EXPORTING i_t_data = lt_data
                                                               i_seperator = cl_abap_char_utilities=>horizontal_tab
                                                               i_flag_header = abap_true ).
 
    CATCH zcx_library.
* get message manager
      DATA lo_api_controller     TYPE REF TO if_wd_controller.
      DATA lo_message_manager    TYPE REF TO if_wd_message_manager.
 
      lo_api_controller ?= wd_this->wd_get_api( ).
 
      lo_message_manager = lo_api_controller->get_message_manager( ).
 
* report message
      lo_message_manager->report_error_message(
          message_text             = 'Error in conversion'
             ).
 
  ENDTRY.
 
* Start download
  DATA lo_interfacecontroller TYPE REF TO ziwci_wdrc_download_file .
  lo_interfacecontroller =   wd_this->wd_cpifc_download_file( ).
 
  lo_interfacecontroller->download_file(
  ).
 
 
ENDMETHOD.

The views are simple, they just have a view container to display the component WD and a table element to display edit. There is also button to navigate between the views.
Upload view

Download view