WebDynpro: Upload and Download file, part II (Download)

For download functionality we have the same process as for Upload. Download WD is created as separate WD component and is referred in the main WD application.

The download logic is as laid out in the diagram below. Event from download component is sent to the main WD component. Which then uses the assistance class to convert the structure into file layout. Then it calls the interface method in the download WD to send the file via the browser to the user for it to be saved.

WD app component using Download WD component.

Download WD Component

This component will download any file that is selected into the internal table of the assistance class. The following has been created in this component.

Layout output (V_DOWNLOAD)

Layout design (V_DOWNLOAD)

Components

Context (V_DOWNLOAD & Component Controller)

There is one difference from the upload WD here, the context has been set to be as interface. The calling WD will the context with file information when it initialises the download WD.

Events

Methods in the main controller

At the component start up get the app name it is embedded in and create structure for mapping the file.

METHOD wddoinit .
  wd_this->app_name = get_app_name( ).
  get_file_struc( ).
  get_date_format( ).
ENDMETHOD.

App name is retrieved here.

METHOD get_app_name .
  DATA lo_api_componentcontroller TYPE REF TO if_wd_component.
  lo_api_componentcontroller = wd_this->wd_get_api( ).
  DATA lo_app TYPE REF TO if_wd_application.
  DATA lo_app_info TYPE REF TO if_wd_rr_application.
  lo_app = lo_api_componentcontroller->get_application( ).
 
  lo_app_info = lo_app->get_application_info( ).
 
  r_app_name = lo_app_info->get_name( ).
ENDMETHOD.

Retrieve the structure for the particular app and create dynamic structure in the assistance class.

METHOD get_file_struc .
  DATA l_struc_name TYPE string.
 
* Look for file structure in the lookup table
  SELECT SINGLE LKP_VALUE INTO l_struc_name
    FROM ZBC_LKP
    WHERE LKP_KEY  = wd_this->app_name.
  IF sy-subrc IS NOT INITIAL.
*       get message manager
    DATA lo_api_controller     TYPE REF TO if_wd_controller.
    DATA lo_message_manager    TYPE REF TO if_wd_message_manager.
 
    lo_api_controller ?= wd_this->wd_get_api( ).
 
    lo_message_manager = lo_api_controller->get_message_manager( ).
 
*       report message
    lo_message_manager->report_error_message(
        message_text             = 'No file structure defined for this app' ).
  ELSE.
* Send the assitance class the structure name
    TRY .
        wd_assist->set_structure_name( i_structure_name = l_struc_name ).
      CATCH zcx_library.
*  report message
        lo_message_manager->report_error_message(
            message_text             = 'File format not supported'
               ).
    ENDTRY.
  ENDIF.
ENDMETHOD.

If date format is specified then use it.

METHOD get_date_format .
  DATA l_date_format TYPE string.
 
* Look for date format in the lookup table
  SELECT SINGLE lkp_value INTO l_date_format
    FROM zbc_lkp
    WHERE lkp_key  = wd_this->app_name.
  IF sy-subrc IS INITIAL.
* Send the assitance class date format
    wd_assist->set_external_date_format( i_date_format = l_date_format ).
  ENDIF.
 
ENDMETHOD.

Now we come to user interactions. Assuming there is data that user wants to download, user will click the download button. Fire event for the App WD for data to be parsed and mapped into a file structure as per the application structure. Once the file structure is created then call the download method to push the file out. The file here is assumed to be tab delimited so that’s what the separator has been specified to.

Action attached to the download button

method ONACTIONDOWNLOAD_FILE .
  wd_comp_controller->start_download( ).
endmethod.

The component controller method start_download is called hence.

METHOD START_DOWNLOAD.
  DATA lo_nd_file TYPE REF TO if_wd_context_node.
  DATA lo_el_file TYPE REF TO if_wd_context_element.
  DATA ls_file TYPE wd_this->element_file.
* navigate from <CONTEXT> to <FILE> via lead selection
  lo_nd_file = wd_context->get_child_node( name = wd_this->wdctx_file ).
 
* get element via lead selection
  lo_el_file = lo_nd_file->get_element(  ).
 
* get all declared attributes
  lo_el_file->get_static_attributes(
    IMPORTING
      static_attributes = ls_file ).
 
* Calling WD should have provided file information
  IF ls_file IS INITIAL.
    throw_message( EXPORTING i_message = 'No file information provided'
                                i_type = if_wd_message_manager=>co_type_error ).
    RETURN.
  ENDIF.
 
  wd_this->file_name = ls_file-filename.
  wd_this->mime_type = ls_file-mimetype.
 
* Fire event
  wd_this->fire_download_clicked_evt( ).
  RETURN.
 
ENDMETHOD.

By this time the calling WD will receive the event and convert the data in to the file structure that it needs to send to. After this it will call the method DOWNLOAD_FILE in the download WD.

METHOD download_file .
  DATA lt_data TYPE TABLE OF string.
  DATA l_data_string TYPE string.
  DATA l_data_xstring TYPE xstring.
 
  wd_assist->get_mapped_file( IMPORTING e_t_mapped_file = lt_data ).
 
  CONCATENATE LINES OF lt_data INTO l_data_string SEPARATED BY cl_abap_char_utilities=>newline.
 
  CALL FUNCTION 'SCMS_STRING_TO_XSTRING'
    EXPORTING
      text   = l_data_string
    IMPORTING
      buffer = l_data_xstring.
 
  cl_wd_runtime_services=>attach_file_to_response( i_filename  = wd_this->file_name
                                                   i_content   = l_data_xstring
                                                   i_mime_type = wd_this->mime_type ).
 
ENDMETHOD.

This covers the download WD component, in part III we will look at the usage of these 2 WD components.

WebDynpro: Upload and Download file, part I (Upload)

As with normal SAPGUI applications there are instances when there is need to write applications that interact with users with a file for sending and receiving data. You might want to upload a list of new Sales Orders or download a list of customers. Like the SAPGUI client there are UI elements here that provide functionality of file services. The approach taken here is to provide a generic file service that can be plugged into any WebDynpro component. Also work done earlier for upload and download in vanilla ABAP is reused.

WD app component using upload WD component

The WD components have been created sharing one assistance class. The WD components will be event driven. When the user clicks to upload/download the file, an event will be raised so that the WD App using the service can be alerted. The calling application can then use the assistance class to receive/send data.

Since the file has to be mapped to a structure, concept of a lookup table is used to decide what structure each application uses. At the initialisation of component a dynamic structure is created in the assistance class.

Assistance class

Assistance class will help the components to create the dynamic structure for each App. This will also map the file into the structure and vice versa. If the input file has a date then app can specify the date format of the input file to convert from. Here are the methods of the assistance class.

CONVERT_DATE2SAP	Instance Method	Private	Convert the external date format to internal SAP date format
SET_EXTERNAL_DATE_FORMAT	Instance Method	Public	Set the external date format to be used in file conversion
GET_MAPPED_FILE	Instance Method	Public	Get the file content mapped in the structure
SET_STRUCTURE_NAME	Instance Method	Public	Set the structure for which data needs to be mapped
CONVERT_STRUC2FILE	Instance Method	Public	Converts structure into file
CONVERT_FILE2STRUC	Instance Method	Public	Converts file into structure

METHOD convert_date2sap.
  DATA l_o_type TYPE REF TO cl_abap_typedescr.
 
* Get the type of the field
  l_o_type = cl_abap_typedescr=>describe_by_data( p_data = i_sap_field   ).
 
* For date type convert from DD.MM.YYYY to YYYYMMDD
  IF l_o_type->type_kind = cl_abap_typedescr=>typekind_date AND
     i_ext_field IS NOT INITIAL AND date_format IS NOT INITIAL.
    TRY.
        IF i_ext_field = '00.00.0000' .    "Ingore 'zero' date.
          CLEAR e_sap_field.
        ELSE.
          CALL METHOD cl_abap_datfm=>conv_date_ext_to_int
            EXPORTING
              im_datext   = i_ext_field
              im_datfmdes = date_format
            IMPORTING
              ex_datint   = e_sap_field.
        ENDIF.
      CATCH cx_abap_datfm_no_date cx_abap_datfm_invalid_date
            cx_abap_datfm_format_unknown cx_abap_datfm_ambiguous .
        e_sap_field = i_ext_field.
        RETURN.
    ENDTRY.
  ELSE.
    e_sap_field = i_ext_field.
  ENDIF.
 
ENDMETHOD.

METHOD SET_EXTERNAL_DATE_FORMAT.
  date_format = i_date_format.
ENDMETHOD.

METHOD get_mapped_file.
  FIELD-SYMBOLS <lt_file_table> TYPE ANY TABLE.
  ASSIGN file_tab->* TO <lt_file_table>.
  e_t_mapped_file[] = <lt_file_table>.
ENDMETHOD.

METHOD set_structure_name.
 
  DATA lo_type TYPE REF TO cl_abap_typedescr.
  DATA lo_tabletype TYPE REF TO cl_abap_tabledescr.
 
  CALL METHOD cl_abap_structdescr=>describe_by_name
    EXPORTING
      p_name         = i_structure_name
    RECEIVING
      p_descr_ref    = lo_type
    EXCEPTIONS
      type_not_found = 1
      OTHERS         = 2.
  IF sy-subrc <> 0.
 
    RAISE EXCEPTION TYPE zcx_library
      EXPORTING
        textid = zcx_library=>incorrect_structure.
  ENDIF.
 
  o_struc_type ?= lo_type.
 
  CREATE DATA file_row TYPE HANDLE o_struc_type.
 
  TRY.
      CALL METHOD cl_abap_tabledescr=>create
        EXPORTING
          p_line_type = o_struc_type
        RECEIVING
          p_result    = lo_tabletype.
    CATCH cx_sy_table_creation .
      RAISE EXCEPTION TYPE zcx_library
        EXPORTING
          textid = zcx_library=>incorrect_structure.
  ENDTRY.
 
  CREATE DATA file_tab TYPE HANDLE lo_tabletype.
 
* Structure mapped successfully
 
ENDMETHOD.

METHOD convert_struc2file.
  DATA:
    l_struc TYPE REF TO data,
    l_o_datadescr TYPE REF TO cl_abap_datadescr,
    l_o_tabledescr TYPE REF TO cl_abap_tabledescr,
    l_t_fields TYPE string_table,
    l_s_fields TYPE string.
  DATA lt_dfies TYPE TABLE OF dfies.
  DATA lst_dfies TYPE dfies.
  DATA l_data_string TYPE string.
  DATA l_column_name TYPE string.
 
  FIELD-SYMBOLS:
    <l_filecontent> TYPE ANY TABLE,
    <l_filerow> TYPE ANY,
    <l_field> TYPE ANY,
    <l_row> TYPE ANY,
    <l_table_content> TYPE table.
 
  ASSIGN file_row->* TO <l_row>.
  ASSIGN file_tab->* TO <l_table_content>.
 
  CLEAR <l_row>.
  CLEAR <l_table_content>.
 
* Check structure mapping has happened first.
  IF o_struc_type IS INITIAL.
    RAISE EXCEPTION TYPE zcx_library
      EXPORTING
        textid = zcx_library=>no_structure_mapped.
  ENDIF.
 
**********************************************************************
  CALL METHOD o_struc_type->get_ddic_field_list
    EXPORTING
      p_including_substructres = abap_true
    RECEIVING
      p_field_list             = lt_dfies.
 
* Add header.
  IF i_flag_header =  abap_true.
    LOOP AT lt_dfies INTO lst_dfies.
      l_column_name = lst_dfies-scrtext_s.
      AT FIRST.
        CONCATENATE l_data_string l_column_name INTO l_data_string.
        CONTINUE.
      ENDAT.
      CONCATENATE l_data_string lst_dfies-scrtext_s INTO l_data_string
                                          SEPARATED BY i_seperator.
      AT LAST.
        CONCATENATE l_data_string cl_abap_char_utilities=>newline INTO l_data_string.
 
      ENDAT.
    ENDLOOP.
  ENDIF.
 
* add the content.
  LOOP AT i_t_data INTO <l_row>.
    WHILE sy-subrc IS INITIAL.
      ASSIGN COMPONENT sy-index OF STRUCTURE <l_row> TO <l_field>.
      IF sy-subrc IS NOT INITIAL.
        EXIT.
      ENDIF.
      IF sy-index = 1.
        CONCATENATE l_data_string <l_field> INTO l_data_string.
        CONTINUE.
      ENDIF.
      CONCATENATE l_data_string <l_field> INTO l_data_string
                              SEPARATED BY i_seperator.
    ENDWHILE.
    CONCATENATE l_data_string cl_abap_char_utilities=>newline INTO l_data_string.
  ENDLOOP.
 
**********************************************************************
  SPLIT l_data_string AT cl_abap_char_utilities=>newline INTO TABLE <l_table_content>.
 
ENDMETHOD.

METHOD convert_file2struc.
  DATA:
    l_struc TYPE REF TO data,
    l_o_datadescr TYPE REF TO cl_abap_datadescr,
    l_o_tabledescr TYPE REF TO cl_abap_tabledescr,
    l_t_fields TYPE string_table,
    l_s_fields TYPE string.
 
  FIELD-SYMBOLS:
    <l_filecontent> TYPE ANY TABLE,
    <l_filerow> TYPE ANY,
    <l_field> TYPE ANY,
    <l_row> TYPE ANY,
    <l_table_content> TYPE table.
 
  ASSIGN file_row->* TO <l_row>.
  ASSIGN file_tab->* TO <l_table_content>.
 
  CLEAR <l_row>.
  CLEAR <l_table_content>.
 
* Check structure mapping has happened first.
  IF <l_row> IS NOT ASSIGNED.
    RAISE EXCEPTION TYPE zcx_library
      EXPORTING
        textid = zcx_library=>no_structure_mapped.
  ENDIF.
* Take out the header
  DATA l_start TYPE i.
  IF i_flag_header = abap_true.
    l_start = 2.
  ELSE.
    l_start = 1.
  ENDIF.
 
  LOOP AT i_t_file_data ASSIGNING <l_filerow> FROM l_start.
    IF i_seperator IS INITIAL. " File is same as structure
      <l_row> = <l_filecontent>.
    ELSE.
*---split based on the separator
      SPLIT <l_filerow> AT i_seperator INTO TABLE l_t_fields.
      LOOP AT l_t_fields INTO l_s_fields.
        ASSIGN COMPONENT sy-tabix OF STRUCTURE <l_row> TO <l_field>.
* If external date format is mentioned then
* convert file content into SAP format
        IF date_format IS NOT INITIAL.
          convert_date2sap( EXPORTING i_sap_field = <l_field>
                                      i_ext_field = l_s_fields
                            IMPORTING e_sap_field = <l_field> ).
        ELSE.
          <l_field> = l_s_fields.
        ENDIF.
      ENDLOOP.
    ENDIF.
    APPEND <l_row> TO <l_table_content>.
  ENDLOOP.
ENDMETHOD.

Upload WD Component

This component will upload any file that is selected into the internal table of the assistance class. The following has been created in this component.

Layout output (V_UPLOAD)

Layout design (V_UPLOAD)

Components

Context (V_UPLOAD & Component Controller)

Events

Methods in the main controller

At the component start up get the app name it is embedded in and create structure for mapping the file.

METHOD wddoinit .
  wd_this->app_name = get_app_name( ).
  get_file_struc( ).
  get_date_format( ).
ENDMETHOD.

App name is retrieved here.

METHOD get_app_name .
  DATA lo_api_componentcontroller TYPE REF TO if_wd_component.
  lo_api_componentcontroller = wd_this->wd_get_api( ).
  DATA lo_app TYPE REF TO if_wd_application.
  DATA lo_app_info TYPE REF TO if_wd_rr_application.
  lo_app = lo_api_componentcontroller->get_application( ).
 
  lo_app_info = lo_app->get_application_info( ).
 
  r_app_name = lo_app_info->get_name( ).
ENDMETHOD.

Retrieve the structure for the particular app and create dynamic structure in the assistance class.

METHOD get_file_struc .
  DATA l_struc_name TYPE string.
 
* Look for file structure in the lookup table
  SELECT SINGLE LKP_VALUE INTO l_struc_name
    FROM ZBC_LKP
    WHERE LKP_KEY  = wd_this->app_name.
  IF sy-subrc IS NOT INITIAL.
*       get message manager
    DATA lo_api_controller     TYPE REF TO if_wd_controller.
    DATA lo_message_manager    TYPE REF TO if_wd_message_manager.
 
    lo_api_controller ?= wd_this->wd_get_api( ).
 
    lo_message_manager = lo_api_controller->get_message_manager( ).
 
*       report message
    lo_message_manager->report_error_message(
        message_text             = 'No file structure defined for this app' ).
  ELSE.
* Send the assitance class the structure name
    TRY .
        wd_assist->set_structure_name( i_structure_name = l_struc_name ).
      CATCH zcx_library.
*  report message
        lo_message_manager->report_error_message(
            message_text             = 'File format not supported'
               ).
    ENDTRY.
  ENDIF.
ENDMETHOD.

If date format is specified then use it.

METHOD get_date_format .
  DATA l_date_format TYPE string.
 
* Look for date format in the lookup table
  SELECT SINGLE lkp_value INTO l_date_format
    FROM zbc_lkp
    WHERE lkp_key  = wd_this->app_name.
  IF sy-subrc IS INITIAL.
* Send the assitance class date format
    wd_assist->set_external_date_format( i_date_format = l_date_format ).
  ENDIF.
 
ENDMETHOD.

Now we come to user interactions. User will select the file and click the upload button. The file will be parsed and mapped into internal table as per the application structure. Once the file is parsed into the internal table fire event for the App WD to receive the internal table. The file here is assumed to be tab delimited so that’s what the separator has been specified to.

Action attached to the upload button

METHOD onactionupload .
 
  wd_comp_controller->upload_file( ).
 
ENDMETHOD.

The component controller method upload_file is called hence.

METHOD upload_file .
 
  DATA s_cont TYPE string.
  DATA convt TYPE REF TO cl_abap_conv_in_ce.
  DATA item_file TYPE xstringval.
 
  DATA t_table TYPE string_table.
 
*  get message manager
  DATA lo_api_controller     TYPE REF TO if_wd_controller.
  DATA lo_message_manager    TYPE REF TO if_wd_message_manager.
 
  lo_api_controller ?= wd_this->wd_get_api( ).
 
  lo_message_manager = lo_api_controller->get_message_manager( ).
 
*  ASSIGN mydate TO  <target_fld>.
 
 
  DATA lo_nd_file TYPE REF TO if_wd_context_node.
  DATA lo_el_file TYPE REF TO if_wd_context_element.
  DATA lv_flag_header TYPE wdy_boolean.
 
* navigate from <CONTEXT> to <FILE> via lead selection
  lo_nd_file = wd_context->get_child_node( name = wd_this->wdctx_file ).
 
* get element via lead selection
  lo_el_file = lo_nd_file->get_element(  ).
 
* get File content
  lo_el_file->get_attribute(
    EXPORTING
      name =  `FILE`
    IMPORTING
      value = item_file ).
 
* get Header flag
  lo_el_file->get_attribute(
    EXPORTING
      name =  `FLAG_HEADER`
    IMPORTING
      value = lv_flag_header ).
 
  TRY.
      convt = cl_abap_conv_in_ce=>create(
                                      encoding = 'UTF-8'
                                      input = item_file ).
      convt->read( IMPORTING data = s_cont  ).
    CATCH cx_sy_conversion_codepage cx_sy_codepage_converter_init
          cx_parameter_invalid_type cx_parameter_invalid_range.
 
*  report message
      lo_message_manager->report_error_message(
          message_text             = 'File format not supported').
      RETURN.
  ENDTRY.
 
  "Column headers
  SPLIT s_cont AT cl_abap_char_utilities=>cr_lf INTO TABLE t_table.
 
* Send the file data
  TRY .
      wd_assist->convert_file2struc(
          i_t_file_data = t_table[]
          i_seperator = cl_abap_char_utilities=>horizontal_tab
          i_flag_header = lv_flag_header
             ).
    CATCH zcx_library.
*  report message
      lo_message_manager->report_error_message(
          message_text             = 'Error processing file'
             ).
      return.
  ENDTRY.
 
  wd_this->fire_upload_clicked_evt( ).
  RETURN.
 
ENDMETHOD.

This covers the upload WD component, in part II we will look at download WD component.